HOME   Trabalhe na Braslink   Indique um amigo

Situação da Rede: ok | Contatos


Voltar ao Index   


Utilizando ASPSMARTUPLOAD

Componente para Upload de arquivos distribuido pela empresa ADVANTYS Smart Enterprise Suite gratuitamente.

O ASPSMARTUPLOAD é suportado pelas plataformas que seguem abaixo :

- Windows NT4 SP6a (IIS3, IIS4)
- Windows 98 (PWS)
- Windows 2000 (IIS5)
- Windows 2003 (IIS6)

- Para seu funcionamento é necessário registrar as DLLs ASPMARTUPLOAD.DLL e ASPMARTUPLOADUTIL.DLL em seu servidor WEB, sem o registro das referidas DLLs o componente não irá funcionar. A Braslink possui o componente devidamente configurado e registrado em TODOS os seus servidores Windows de produção.

-Após realizar a instalação do serviço e registrar as DLLs é necessário configurar os atributos globais e individuais do componente. Isso poderá ser feito através dos registros do componentes uma vez instalados na máquina, através da chave que segue abaixo :

HKEY_LOCAL_MACHINESOFTWAREAdvantysaspSmartUpload

A) Como funciona o componente.
O Componente é bastante simples de ser utilizado. Devemos primeiro criar um documento HTML para que possamos localizar os arquivos na Workstation do cliente.
Exemplo 1 - Upload.HTML

<HTML>
<BODY BGCOLOR="white">
<H1>aspSmartUpload: Sample 1</H1>
<HR><FORM METHOD="POST" ACTION="sample1.asp" ENCTYPE="multipart/form-data">
<INPUT TYPE="FILE" NAME="FILE1" SIZE="50"><BR>
<INPUT TYPE="FILE" NAME="FILE2" SIZE="50"><BR>
<INPUT TYPE="FILE" NAME="FILE3" SIZE="50"><BR>
<INPUT TYPE="FILE" NAME="FILE4" SIZE="50"><BR>
<INPUT TYPE="SUBMIT" VALUE="Upload">
</FORM>
</BODY>
</HTML>

Salve o arquivo com o nome de upload.htm
Algumas observações:

- A TAG HTML utilizada para localização de arquivos na estação do cliente é do tipo "FILE", semelhante ao "TEXT", porém ela insere um botão para localização de arquivos na estação do cliente.

- Cada campo "FILE" foi identificado com um "NOME" diferente, para que ao realizar o Upload, os arquivos possam ser identificados separadamente pelo ASP. Os nomes utilizados foram respectivamente "FILE1, FILE2, FILE3 e FILE4". qualquer nome pode ser utilizado, desde os nomes sejam diferentes.

- O arquivo upload.htm está enviando as informações para o arquivo sample1.asp, que deverá processar o upload dos arquivos no servidor.Agora devemos criar o arquivo ASP (no caso sample1.asp) que criará o objeto de upload e armazenará os arquivos no servidor.

<HTML>
<BODY BGCOLOR="white">
<H1>aspSmartUpload : exemplo 1</H1>
<HR>
<%

' Variáveis
' ***************
Dim mySmartUpload
Dim intCount

' Criação do Objeto
' ***************
Set mySmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")

' Upload
' ******
mySmartUpload.Upload

' Salva os arquivos com seus nomes originais em um caminho VIRTUAL do servidor
' ****************************************************************************
intCount = mySmartUpload.Save("upload")
' Exemplo com o caminho físico do servidor
' intCount = mySmartUpload.Save("c: emp")

' Exibe o número de arquivos enviados com sucesso
' ************************************
Response.Write(intCount &" arquivo(s) enviados.")
%>
</BODY>
</HTML>

Exemplo 2 - pegando as informações dos arquivos enviados

Nesse exemplo iremos exibir no navegador as informações dos arquivos enviados pelo componente ASPMSARTUPLOAD. Devemos criar um novo documento HTML como o do exemplo 1, no entanto seu ACTION deverá estar apontando para o arquivo "sample2.asp" para que funcione corretamente. O arquivo sample2.asp deverá ficar como segue :

<HTML>
<BODY BGCOLOR="white">
<H1>aspSmartUpload : Exemplo 2</H1>
<HR>
<%

' Variáveis
' *********
Dim mySmartUpload
Dim file
Dim intCount
intCount=0

' Cria o objeto
' ***************
Set mySmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")

' Upload
' ******
mySmartUpload.Upload

' Seleciona cada arquivo
' ****************
For each file In mySmartUpload.Files

' Somente se o arquivo existir
' **********************
If not file.IsMissing Then

' Salva os arquivos com seu nome original em um caminho virtual
' **************************************************************************
file.SaveAs("upload" & file.FileName)
' Exemplo com o caminho físico do servidor
' file.SaveAs("c: emp" & file.FileName)

' Exibe as propriedades atuais do arquivo enviado
' ******************************************
Response.Write("Nome = " & file.Name & "<BR>")
Response.Write("Tamanho = " & file.Size & "<BR>")
Response.Write("Nome do Arquivo = " & file.FileName & "<BR>")
Response.Write("Extensão do arquivo = " & file.FileExt & "<BR>")
Response.Write("Nome original do Arquivo = " & file.FilePathName & "<BR>")
Response.Write("Conteúdo = " & file.ContentType & "<BR>")
Response.Write("TypeMIME = " & file.TypeMIME & "<BR>")
Response.Write("SubTypeMIME = "& file.SubTypeMIME & "<BR><BR>")
intCount = intCount + 1
End If
Next

' Exibe o número de arquivos que poderiam ser enviados
' ***************************************************
Response.Write("<BR>"& mySmartUpload.Files.Count & " Arquivos que poderiam ser enviados.<BR>")

' Exibe o número de arquivos enviados
' ************************************
Response.Write(intCount & " arquivo(s) enviados.<BR>")
%>
</BODY>
</HTML>

Exemplo 3 - Restringindo o envio de arquivos para o servidor WEB

Neste exemplo, utilizando o conhecimento e as informações dos arquivos enviados ao servidor, iremos restringir o Upload de arquivos pela sua extensão ou tamanho. Para isso devemos criar um arquivo HTML como o do exemplo 1 mas com seu ACTION apontado para o arquivo "sample3.asp" para que funcione corretamente. O arquivo sample3.asp deverá ficar como segue abaixo :

<HTML>
<BODY BGCOLOR="white">
<H1>aspSmartUpload : exemplo 3</H1>
<HR>
<%
On Error Resume Next

' Variáveis
' *********
Dim mySmartUpload
Dim intCount

' Criação do objeto
' ***************
Set mySmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")

' Concede permissão para envio de arquivo específicados no Objeto AllowedFilesList
' ***************************
mySmartUpload.AllowedFilesList = "htm,txt,jpg"

' DeniedFilesList pode ser usado para bloquear arquivos
' Permite todos os tipos de arquivos, comexcessão de exe, bat and asp
'***************************************
' mySmartUpload.DeniedFilesList = "exe,bat,asp"

' Não permite que o caminho físico da máquina seja exibido
*******************
mySmartUpload.DenyPhysicalPath = True

' Permite apenas o envio de arquivos menores que 50000 bytes
' *****************************************
mySmartUpload.MaxFileSize = 50000

' Não permite o envio de arquivo maiores que 200000 bytes
' ***************************************************************
mySmartUpload.TotalMaxFileSize = 200000

' Upload
' ******
mySmartUpload.Upload

' Salva o arquivo com seu nome original em um caminho VIRTUAL
' ****************************************************************************
intCount = mySmartUpload.Save("upload")
' Exemplo com um caminho físico
' intCount = mySmartUpload.Save("c: emp")

' Mensagens de erro
' ***********
If Err Then
Response.Write("<b>Arquivo não permitido : </b>" & Err.description)
Else

' Exibe o número de arquivos enviados
' ************************************
Response.Write(intCount & " Arquivo(s) Enviados.")
End If

%>
</BODY>
</HTML>


    Painel de Controle

    Através do Painel de Controle tenha acesso a pagamentos, troca de plano e configurações de seu domínio.

  • Seu IP: 23.23.50.247
    Esqueceu sua Senha ?

    Ajuda e Suporte
Privacidade |  Seguraça |  SLA |  Ajuda |  DataCenter |  Anti-SPAM |  Entre em contato | 
Braslink Network Inc.